MODULE CMD_TABLE
IDENT "V4.9"
!++
!
! DESCRIPTION:
!
!   This is the command table used by the NEWS utility for internal
!   NEWS commands.
!
! AUTHOR:   	    M. Madison
!   	    	    COPYRIGHT © 1992, 1993, 1994, 1995, 1996  MADGOAT SOFTWARE.
!   	    	    ALL RIGHTS RESERVED.
!
! CREATION DATE:    15-MAR-1989
!
! MODIFICATION HISTORY:
!
!   15-MAR-1989	V1.0-1  Madison     Initial coding.
!   02-JUN-1989	V1.1-2  Madison     Change DIRECTORY command to take
!   	    	    	    	    starting article number, not groupname.
!   	    	    	    	    Ditched stupid /ALL qualifier on DIR.
!   05-JUN-1989	V1.1-3  Madison     Allow REPLY/POST/MAIL.
!   05-JUN-1989	V1.1-4  Madison     Add /LAST, /FIRST to READ command.
!   15-FEB-1990	V1.2-5	Madison	    Add /FOLLOW to POST, REPLY.
!   16-FEB-1990	V2.0	Madison	    DIR/SUBJ/KEYW/AUTH.
!   21-FEB-1990	V2.0-1	Madison	    Provide fspec default on EXTRACT.
!   01-MAR-1990	V2.1-2	Madison	    Add /[NO]SELF to MAIL, REPLY commands.
!   23-MAY-1990	V2.2-3	Madison	    Add READ/PREVIOUS.
!   28-JUN-1990	V2.3-4	Madison	    Modify SET EDIT/EDITOR.
!   08-JAN-1991	V2.4	Madison	    SET SIG/AUTO change. SET REPLY. READ/SUBJ.
!                                   REPLY/TO. DIR/WIDTH.
!   08-FEB-1991	V2.5	Madison	    SET NOSEEN.  REPLY/GROUP.
!   11-OCT-1991	V3.0	Madison	    Change default on UPDATE command.
!   14-NOV-1991	V3.0-1	Madison	    Add PREVIOUS, BACK as synonymos for READ/P.
!   22-NOV-1991	V3.0-2	Madison	    Allow input file on POST command.
!   04-JUN-1992	V3.1	Madison	    SET IGNORE/NEWSGROUPS.  READ/NEXT/GROUP/NEW.
!   11-SEP-1992	X4.0	Madison	    Added SUB/LOG, UNSUB/LOG, SET NEWSRC
!   12-SEP-1992	X4.0-1	Madison	    Added SET DIR, SET FORM, SET QUEUE.
!   12-SEP-1992	X4.0-2	Madison	    Added SUB/GOTO.
!   15-SEP-1992	X4.0-3	Madison	    Added DIR/GROUP/SORT.
!   08-OCT-1992	V4.0-4	Madison	    Added SHOW VERSION.
!   15-FEB-1993	V4.1	Madison	    Added SET SEEN/SUBJECT, /CROSS.
!   12-APR-1993	V4.2	Madison	    Added CUR/ED, SET AUTO_READ_NEW.
!   23-APR-1993	V4.2-1	Madison	    Added SET FORCE_MAIL_PROTOCOL, NEWGROUP_ACTION
!   23-MAY-1993	V4.2-2	Madison	    Changed SET SEEN.
!   22-JUN-1993	A4.3	Madison	    Add SET AUTO_SAVE_PROFILE
!   21-SEP-1993	V4.3	Madison	    Add POST/APPROVED, /EXPIRATION.
!   09-OCT-1993	V4.5	Madison	    New commands, DIR changes.
!   26-OCT-1993	V4.5-1	Madison	    Missing header keyword CONTROL.
!   16-MAR-1994	V4.6	Madison	    Add SET IGNORE/MESSAGE_ID.
!   16-MAY-1994	V4.8	Madison	    Add SET REPLY/PREFIX.
!   27-JAN-1996	V4.9	Madison	    Add SET THREAD_MODE, DIR/NOTHREAD.
!--

DEFINE VERB EXIT
    ROUTINE CMD_EXIT
    SYNONYM E
    SYNONYM EX

DEFINE VERB PREVIOUS
    SYNONYM BACK
    ROUTINE CMD_READPREV
    NOPARAMETERS

DEFINE VERB READ
    QUALIFIER NEXT, NONNEGATABLE, SYNTAX=READNEXT
    QUALIFIER NEW, NONNEGATABLE, SYNTAX=READNEW
    QUALIFIER PREVIOUS, NONNEGATABLE, SYNTAX=READPREV
    QUALIFIER THREAD, NONNEGATABLE, SYNTAX=READTHREAD
    ROUTINE CMD_READ
    PARAMETER P1, LABEL=ARTNUM, PROMPT="Article number"
    QUALIFIER SUBJECT, NONNEGATABLE, VALUE (LIST)
    QUALIFIER GROUP, NONNEGATABLE, VALUE (REQUIRED)
    QUALIFIER FIRST, NONNEGATABLE
    QUALIFIER LAST, NONNEGATABLE
    DISALLOW ANY2 (FIRST, LAST, SUBJECT, ARTNUM)

DEFINE VERB FIRST
    ROUTINE CMD_READ
    NOPARAMETERS
    QUALIFIER GROUP, NONNEGATABLE, VALUE (REQUIRED)

DEFINE VERB LAST
    ROUTINE CMD_READ
    NOPARAMETERS
    QUALIFIER GROUP, NONNEGATABLE, VALUE (REQUIRED)

DEFINE SYNTAX READNEW
    ROUTINE CMD_READNEW
    NOQUALIFIERS
    NOPARAMETERS

DEFINE SYNTAX READNEXT
    QUALIFIER NEW, NONNEGATABLE, SYNTAX=READNEXTNEW
    NOPARAMETERS
    ROUTINE CMD_READNEXT

DEFINE SYNTAX READPREV
    NOPARAMETERS
    ROUTINE CMD_READPREV

DEFINE SYNTAX READTHREAD
    ROUTINE CMD_READTHREAD
    NOPARAMETERS
    QUALIFIER NEW, NONNEGATABLE
    QUALIFIER STRICT, NEGATABLE

DEFINE SYNTAX READNEXTNEW
    QUALIFIER GROUP, NONNEGATABLE, SYNTAX=READNEXTNEWGROUP
    ROUTINE CMD_READNEXTNEW
    NOPARAMETERS

DEFINE VERB NEXT
    QUALIFIER GROUP, NONNEGATABLE, SYNTAX=READNEXTNEWGROUP
    ROUTINE CMD_NEXT
    NOPARAMETERS

DEFINE SYNTAX READNEXTNEWGROUP
    ROUTINE CMD_READNEXTNEWGROUP
    NOPARAMETERS
    NOQUALIFIERS

DEFINE SYNTAX DIRGROUP
    ROUTINE CMD_DIRGROUP
    PARAMETER P1, LABEL=GRPNAM
    QUALIFIER SORT, NEGATABLE
    QUALIFIER ALL, NONNEGATABLE
    QUALIFIER UNSEEN, NONNEGATABLE

DEFINE VERB DIRECTORY
    QUALIFIER GROUP, NONNEGATABLE, SYNTAX=DIRGROUP
    ROUTINE CMD_DIR
    PARAMETER P1, LABEL=ARTRNG
    QUALIFIER FROM, NONNEGATABLE, VALUE (REQUIRED, LIST)
    QUALIFIER SUBJECT, NONNEGATABLE, VALUE (REQUIRED, LIST)
    QUALIFIER KEYWORD, NONNEGATABLE, VALUE (REQUIRED, LIST)
    QUALIFIER WIDTH, NONNEGATABLE, VALUE (REQUIRED, LIST, TYPE=DIRWIDTHS)
    QUALIFIER SEEN, NEGATABLE
    QUALIFIER UNSEEN, NONNEGATABLE
    QUALIFIER EXCLUDE, NONNEGATABLE, VALUE (REQUIRED, LIST, TYPE=EXCLUDES)
    QUALIFIER THREAD, NEGATABLE
    QUALIFIER STRICT
    DISALLOW (STRICT AND NOT THREAD)

DEFINE TYPE DIRWIDTHS
    KEYWORD FROM, NONNEGATABLE, VALUE (REQUIRED, TYPE=$NUMBER)
    KEYWORD SUBJECT, NONNEGATABLE, VALUE (REQUIRED, TYPE=$NUMBER)

DEFINE TYPE EXCLUDES
    KEYWORD FROM, NONNEGATABLE, VALUE (REQUIRED, LIST)
    KEYWORD SUBJECT, NONNEGATABLE, VALUE (REQUIRED, LIST)

DEFINE VERB GROUP
    ROUTINE CMD_GROUP
    PARAMETER P1, LABEL=GRPNAM, PROMPT="Group name", VALUE (REQUIRED)

DEFINE VERB CURRENT
    ROUTINE CMD_CURRENT
    NOPARAMETERS
    QUALIFIER ROTATE
    QUALIFIER EDIT
    QUALIFIER FULL_HEADERS
    QUALIFIER THREAD_BASE, NONNEGATABLE

DEFINE VERB REPLY
    ROUTINE CMD_REPLY
    SYNONYM FOLLOWUP
    SYNONYM RE
    SYNONYM R
    PARAMETER P1, LABEL=GRPNAM, PROMPT="Group name", VALUE (LIST)
    QUALIFIER MAIL, NONNEGATABLE
    QUALIFIER POST, NONNEGATABLE
    QUALIFIER EDIT, NEGATABLE
    QUALIFIER EXTRACT, NEGATABLE
    QUALIFIER SUBJECT, NEGATABLE, VALUE (DEFAULT="")
    QUALIFIER SIGNATURE, NEGATABLE
    QUALIFIER DISTRIBUTION, NONNEGATABLE, VALUE (REQUIRED, LIST)
    QUALIFIER FOLLOWUP_TO, NONNEGATABLE, VALUE (REQUIRED, LIST)
    QUALIFIER SELF, NEGATABLE
    QUALIFIER TO, NONNEGATABLE, VALUE (REQUIRED, LIST)
    QUALIFIER APPROVED, NONNEGATABLE
    QUALIFIER EXPIRATION, VALUE (REQUIRED, TYPE=$DATETIME)
    QUALIFIER KEYWORDS, VALUE (REQUIRED, LIST)
    QUALIFIER SUMMARY, VALUE (REQUIRED)

DEFINE VERB POST
    ROUTINE CMD_POST
    PARAMETER P1, LABEL=GRPNAM, PROMPT="Group name", VALUE (LIST)
    PARAMETER P2, LABEL=INPFIL, VALUE (TYPE=$FILE)
    QUALIFIER EDIT, NEGATABLE
    QUALIFIER SUBJECT, NEGATABLE, VALUE (DEFAULT="")
    QUALIFIER SIGNATURE, NEGATABLE
    QUALIFIER DISTRIBUTION, NONNEGATABLE, VALUE (REQUIRED, LIST)
    QUALIFIER FOLLOWUP_TO, NONNEGATABLE, VALUE (REQUIRED, LIST)
    QUALIFIER FILE, NONNEGATABLE, VALUE (REQUIRED, TYPE=$FILE)
    QUALIFIER APPROVED, NONNEGATABLE
    QUALIFIER EXPIRES, VALUE (REQUIRED, TYPE=$DATETIME)
    QUALIFIER KEYWORDS, VALUE (REQUIRED, LIST)
    QUALIFIER SUMMARY, VALUE (REQUIRED)

DEFINE VERB MAIL
    ROUTINE CMD_MAIL
    SYNONYM SEND
    PARAMETER P1, LABEL=FSPEC, VALUE (TYPE=$FILE)
    QUALIFIER EDIT, NEGATABLE
    QUALIFIER SUBJECT, NEGATABLE, VALUE (DEFAULT="")
    QUALIFIER SIGNATURE, NEGATABLE
    QUALIFIER TO, NONNEGATABLE, VALUE (REQUIRED, LIST)
    QUALIFIER SELF, NEGATABLE

DEFINE VERB FORWARD
    ROUTINE CMD_FORWARD
    PARAMETER P1, LABEL=ARTNUM, VALUE (TYPE=$NUMBER)
    QUALIFIER EDIT, NEGATABLE
    QUALIFIER SUBJECT, NEGATABLE, VALUE (DEFAULT="")
    QUALIFIER SIGNATURE, NEGATABLE
    QUALIFIER TO, NONNEGATABLE, VALUE (REQUIRED, LIST)
    QUALIFIER SELF, NEGATABLE

DEFINE VERB STORE
    ROUTINE CMD_FORWARD
    PARAMETER P1, LABEL=ARTNUM, VALUE (TYPE=$NUMBER)
    NOQUALIFIERS

DEFINE VERB SUBSCRIBE
    ROUTINE CMD_SUBSCRIBE
    PARAMETER P1, LABEL=GRPNAM, PROMPT="Group name", VALUE (REQUIRED, LIST)
    QUALIFIER CONFIRM, NEGATABLE
    QUALIFIER LOG, NEGATABLE
    QUALIFIER GOTO, NONNEGATABLE

DEFINE VERB UNSUBSCRIBE
    ROUTINE CMD_UNSUBSCRIBE
    PARAMETER P1, LABEL=GRPNAM, PROMPT="Group name", VALUE (LIST)
    QUALIFIER CONFIRM, NEGATABLE
    QUALIFIER LOG, NEGATABLE

DEFINE TYPE SHOW_KWDS
    KEYWORD HEADERS, NONNEGATABLE
    KEYWORD PERSONAL_NAME, NONNEGATABLE
    KEYWORD EDIT, NONNEGATABLE
    KEYWORD SERVER, NONNEGATABLE
    KEYWORD CURRENT_GROUP, NONNEGATABLE
    KEYWORD GROUP, NONNEGATABLE
    KEYWORD SIGNATURE_FILE, NONNEGATABLE
    KEYWORD ARCHIVE_DIRECTORY, NONNEGATABLE
    KEYWORD REPLY, NONNEGATABLE
    KEYWORD IGNORE, NONNEGATABLE, SYNTAX=SHOW_IGNORE
    KEYWORD NEWSRC, NONNEGATABLE
    KEYWORD DIRECTORY_WIDTH, NONNEGATABLE
    KEYWORD QUEUE, NONNEGATABLE
    KEYWORD FORM, NONNEGATABLE
    KEYWORD VERSION, NONNEGATABLE
    KEYWORD AUTO_READ_NEW, NONNEGATABLE
    KEYWORD FORCE_MAIL_PROTOCOL, NONNEGATABLE
    KEYWORD NEWGROUP_ACTION, NONNEGATABLE
    KEYWORD AUTO_SAVE_PROFILE, NONNEGATABLE
    KEYWORD THREAD_MODE, NONNEGATABLE
    KEYWORD ALL, NONNEGATABLE

DEFINE VERB SHOW
    ROUTINE CMD_SHOW
    PARAMETER P1, LABEL=SHOWKW, PROMPT="Show what?",
    	VALUE (REQUIRED, TYPE=SHOW_KWDS, LIST)
    NOQUALIFIERS

DEFINE SYNTAX SHOW_IGNORE
    PARAMETER P1, LABEL=SHOWKW, PROMPT="Show what?",
    	VALUE (REQUIRED, TYPE=SHOW_KWDS, LIST)
    PARAMETER P2, LABEL=GRPNAM, VALUE (LIST)
    QUALIFIER GLOBAL, NONNEGATABLE
    QUALIFIER LOCAL, NONNEGATABLE

DEFINE VERB SET
    PARAMETER P1, LABEL=SETKW, PROMPT="Option", VALUE (REQUIRED, TYPE=SET_KWDS)
    NOQUALIFIERS

DEFINE TYPE SET_KWDS
    KEYWORD HEADERS, SYNTAX=SET_HEADERS, NEGATABLE
    KEYWORD PERSONAL_NAME, SYNTAX=SET_PERS, NEGATABLE
    KEYWORD EDIT, SYNTAX=SET_ED, NEGATABLE
    KEYWORD REPLY, SYNTAX=SET_REPLY, NONNEGATABLE
    KEYWORD SEEN, SYNTAX=SET_SEEN, NONNEGATABLE
    KEYWORD UNSEEN, SYNTAX=SET_UNSEEN, NONNEGATABLE
    KEYWORD SIGNATURE_FILE, SYNTAX=SET_SIG, NEGATABLE
    KEYWORD ARCHIVE_DIRECTORY, SYNTAX=SET_ARCHIVE, NEGATABLE
    KEYWORD IGNORE, SYNTAX=SET_IGNORE, NEGATABLE
    KEYWORD NEWSRC, SYNTAX=SET_NEWSRC, NEGATABLE
    KEYWORD QUEUE, SYNTAX=SET_QUEUE, NONNEGATABLE
    KEYWORD FORM, SYNTAX=SET_FORM, NEGATABLE
    KEYWORD DIRECTORY_WIDTH, SYNTAX=SET_DIR, NONNEGATABLE
    KEYWORD AUTO_READ_NEW, SYNTAX=SET_ARN, NEGATABLE
    KEYWORD FORCE_MAIL_PROTOCOL, SYNTAX=SET_FMP, NEGATABLE
    KEYWORD NEWGROUP_ACTION SYNTAX=SET_NGA, NONNEGATABLE
    KEYWORD AUTO_SAVE_PROFILE, SYNTAX=SET_ASP, NEGATABLE
    KEYWORD THREAD_MODE, SYNTAX=SET_RBT, NEGATABLE

DEFINE SYNTAX SET_HEADERS
    ROUTINE CMD_SET_HEADERS
    PARAMETER P1, LABEL=SETKW, PROMPT="Option", VALUE (REQUIRED, TYPE=SET_KWDS)
    PARAMETER P2, LABEL=HDRNAM, PROMPT="Header", VALUE (TYPE=HEADER_KWDS, LIST)
    QUALIFIER INTERACTIVE, NONNEGATABLE
    QUALIFIER EXTRACT, NONNEGATABLE
    DISALLOW INTERACTIVE AND EXTRACT

DEFINE TYPE HEADER_KWDS
    KEYWORD FROM, NEGATABLE
    KEYWORD DATE, NEGATABLE
    KEYWORD NEWSGROUPS, NEGATABLE
    KEYWORD SUBJECT, NEGATABLE
    KEYWORD MESSAGE_ID, NEGATABLE
    KEYWORD PATH, NEGATABLE
    KEYWORD REPLY_TO, NEGATABLE
    KEYWORD SENDER, NEGATABLE
    KEYWORD FOLLOWUP_TO, NEGATABLE
    KEYWORD EXPIRES, NEGATABLE
    KEYWORD REFERENCES, NEGATABLE
    KEYWORD CONTROL, NEGATABLE
    KEYWORD DISTRIBUTION, NEGATABLE
    KEYWORD ORGANIZATION, NEGATABLE
    KEYWORD KEYWORDS, NEGATABLE
    KEYWORD SUMMARY, NEGATABLE
    KEYWORD APPROVED, NEGATABLE
    KEYWORD LINES, NEGATABLE
    KEYWORD XREF, NEGATABLE
    KEYWORD OTHER, NEGATABLE

DEFINE SYNTAX SET_PERS
    ROUTINE CMD_SET_PERSNAM
    PARAMETER P1, LABEL=SETKW, PROMPT="Option", VALUE (REQUIRED, TYPE=SET_KWDS)
    PARAMETER P2, LABEL=PERSNAM, PROMPT="Name"
    QUALIFIER MAIL, NONNEGATABLE

DEFINE SYNTAX SET_REPLY
    ROUTINE CMD_SET_REPLY
    PARAMETER P1, LABEL=SETKW, PROMPT="Option", VALUE (REQUIRED, TYPE=SET_KWDS)
    PARAMETER P2, LABEL=REPLYTYPE, PROMPT="Reply type",
    	VALUE (LIST, TYPE=REPLY_KWDS)
    QUALIFIER PREFIX, VALUE (REQUIRED), NEGATABLE

DEFINE TYPE REPLY_KWDS
    KEYWORD MAIL
    KEYWORD POST

DEFINE SYNTAX SET_ED
    ROUTINE CMD_SET_EDIT
    PARAMETER P1, LABEL=SETKW, PROMPT="Option", VALUE (REQUIRED, TYPE=SET_KWDS)
    QUALIFIER EDITOR, NONNEGATABLE, VALUE (REQUIRED,LIST)

DEFINE SYNTAX SET_SEEN
    ROUTINE CMD_SET_SEEN
    QUALIFIER ALL, NONNEGATABLE, SYNTAX=MARK_ALL
    QUALIFIER SUBJECT, NONNEGATABLE, VALUE (REQUIRED, LIST)
    QUALIFIER CROSS_REFERENCES
    QUALIFIER THREAD
    QUALIFIER STRICT
    PARAMETER P1, LABEL=SETKW, PROMPT="Option", VALUE (REQUIRED, TYPE=SET_KWDS)
    PARAMETER P2, LABEL=ARTRNG, PROMPT="Article number",
    	VALUE (LIST)
    DISALLOW (THREAD AND SUBJECT)
    DISALLOW (STRICT AND NOT THREAD)

DEFINE SYNTAX SET_UNSEEN
    ROUTINE CMD_SET_SEEN
    QUALIFIER ALL, NONNEGATABLE, SYNTAX=MARK_ALL
    QUALIFIER SUBJECT, NONNEGATABLE, VALUE (REQUIRED, LIST)
    QUALIFIER CROSS_REFERENCES
    QUALIFIER THREAD
    PARAMETER P1, LABEL=SETKW, PROMPT="Option", VALUE (REQUIRED, TYPE=SET_KWDS)
    PARAMETER P2, LABEL=ARTRNG, PROMPT="Article number",
    	VALUE (LIST)
    DISALLOW (THREAD AND SUBJECT)

DEFINE SYNTAX SET_SIG
    ROUTINE CMD_SET_SIG
    PARAMETER P1, LABEL=SETKW, PROMPT="Option", VALUE (REQUIRED, TYPE=SET_KWDS)
    PARAMETER P2, LABEL=SIGFILE, VALUE (TYPE=$FILE)
    QUALIFIER AUTOMATIC, NEGATABLE, VALUE (LIST, TYPE=AUTO_KWDS)

DEFINE TYPE AUTO_KWDS
    KEYWORD MAIL, NEGATABLE
    KEYWORD POST, NEGATABLE

DEFINE SYNTAX SET_ARCHIVE
    ROUTINE CMD_SET_ARCHIVE
    PARAMETER P1, LABEL=SETKW, PROMPT="Option", VALUE (REQUIRED, TYPE=SET_KWDS)
    PARAMETER P2, LABEL=ARCHIVE, VALUE (TYPE=$FILE)
    NOQUALIFIERS

DEFINE SYNTAX SET_IGNORE
    ROUTINE CMD_SET_IGNORE
    PARAMETER P1, LABEL=SETKW, PROMPT="Option", VALUE (REQUIRED, TYPE=SET_KWDS)
    PARAMETER P2, LABEL=GRPNAM
    QUALIFIER FROM, NONNEGATABLE, VALUE (REQUIRED)
    QUALIFIER SUBJECT, NONNEGATABLE, VALUE (REQUIRED)
    QUALIFIER NEWSGROUPS, NONNEGATABLE, VALUE (REQUIRED)
    QUALIFIER MESSAGE_ID, NONNEGATABLE, VALUE (REQUIRED)
    QUALIFIER PATH, NONNEGATABLE, VALUE (REQUIRED)
    QUALIFIER GLOBAL, NONNEGATABLE
    DISALLOW ANY2 (FROM, SUBJECT, NEWSGROUPS, MESSAGE_ID, PATH)

DEFINE SYNTAX MARK_ALL
    PARAMETER P1, LABEL=SETKW, PROMPT="Option", VALUE (REQUIRED, TYPE=SET_KWDS)

DEFINE SYNTAX SET_NEWSRC
    ROUTINE CMD_SET_NEWSRC
    PARAMETER P1, LABEL=SETKW, PROMPT="Option", VALUE (REQUIRED, TYPE=SET_KWDS)
    PARAMETER P2, LABEL=NEWSRC_FILE, VALUE (TYPE=$FILE)
    QUALIFIER SUBSCRIBED_ONLY, NEGATABLE
    QUALIFIER PURGE, NEGATABLE

DEFINE SYNTAX SET_QUEUE
    ROUTINE CMD_SET_QUEUE
    PARAMETER P1, LABEL=SETKW, PROMPT="Option", VALUE (REQUIRED, TYPE=SET_KWDS)
    PARAMETER P2, LABEL=QUENAME, PROMPT="Queue name", VALUE (REQUIRED)
    NOQUALIFIERS

DEFINE SYNTAX SET_FORM
    ROUTINE CMD_SET_FORM
    PARAMETER P1, LABEL=SETKW, PROMPT="Option", VALUE (REQUIRED, TYPE=SET_KWDS)
    PARAMETER P2, LABEL=FORMNAME
    NOQUALIFIERS

DEFINE SYNTAX SET_DIR
    ROUTINE CMD_SET_DIR
    PARAMETER P1, LABEL=SETKW, PROMPT="Option", VALUE (REQUIRED, TYPE=SET_KWDS)
    QUALIFIER FROM, VALUE(REQUIRED, TYPE=$NUMBER)
    QUALIFIER SUBJECT, VALUE(REQUIRED, TYPE=$NUMBER)

DEFINE SYNTAX SET_ARN
    ROUTINE CMD_SET_ARN
    PARAMETER P1, LABEL=SETKW, PROMPT="Option", VALUE (REQUIRED, TYPE=SET_KWDS)
    NOQUALIFIERS

DEFINE SYNTAX SET_ASP
    ROUTINE CMD_SET_ASP
    PARAMETER P1, LABEL=SETKW, PROMPT="Option", VALUE (REQUIRED, TYPE=SET_KWDS)
    NOQUALIFIERS

DEFINE SYNTAX SET_FMP
    ROUTINE CMD_SET_FMP
    PARAMETER P1, LABEL=SETKW, PROMPT="Option", VALUE (REQUIRED, TYPE=SET_KWDS)
    NOQUALIFIERS

DEFINE TYPE NGA_KWDS
    KEYWORD NONE, NONNEGATABLE
    KEYWORD PROMPT, NONNEGATABLE
    KEYWORD SUBSCRIBE, NONNEGATABLE

DEFINE SYNTAX SET_NGA
    ROUTINE CMD_SET_NGA
    PARAMETER P1, LABEL=SETKW, PROMPT="Option", VALUE (REQUIRED, TYPE=SET_KWDS)
    PARAMETER P2, LABEL=NGAKW, PROMPT="Action", VALUE (REQUIRED, TYPE=NGA_KWDS)
    NOQUALIFIERS

DEFINE SYNTAX SET_RBT
    ROUTINE CMD_SET_RBT
    PARAMETER P1, LABEL=SETKW, PROMPT="Option", VALUE (REQUIRED, TYPE=SET_KWDS)
    QUALIFIER STRICT, NEGATABLE

DEFINE VERB UPDATE
    ROUTINE CMD_UPDATE_FULL
    QUALIFIER PARTIAL, SYNTAX=UPDPARTIAL
    QUALIFIER FULL, NONNEGATABLE
    NOPARAMETERS

DEFINE SYNTAX UPDPARTIAL
    ROUTINE CMD_UPDATE
    NOQUALIFIERS
    NOPARAMETERS

DEFINE VERB HELP
    ROUTINE CMD_HELP
    PARAMETER P1, LABEL=TOPIC, VALUE (TYPE=$REST_OF_LINE)
    NOQUALIFIERS

DEFINE VERB SPAWN
    ROUTINE CMD_SPAWN
    PARAMETER P1, LABEL=CMD, VALUE (TYPE=$REST_OF_LINE)
    QUALIFIER INPUT, NONNEGATABLE, VALUE (REQUIRED, TYPE=$FILE)
    QUALIFIER LOGICAL_NAMES, NEGATABLE
    QUALIFIER OUTPUT, NONNEGATABLE, VALUE (REQUIRED, TYPE=$FILE)
    QUALIFIER PROCESS, NONNEGATABLE, VALUE (DEFAULT="")
    QUALIFIER SYMBOLS, NEGATABLE
    QUALIFIER WAIT, NEGATABLE

DEFINE VERB ATTACH
    ROUTINE CMD_ATTACH
    PARAMETER P1, LABEL=PRCNAM
    QUALIFIER PARENT, NONNEGATABLE

DEFINE VERB EXTRACT
    ROUTINE CMD_EXTRACT
    SYNONYM SAVE
    PARAMETER P1, LABEL=FSPEC, PROMPT="Filename", VALUE (TYPE=$FILE)
    PARAMETER P2, LABEL=ARTRNG, VALUE (LIST)
    QUALIFIER APPEND, NEGATABLE
    QUALIFIER HEADERS, NEGATABLE, VALUE (TYPE=EXTRACT_KWDS)
    QUALIFIER ROTATE
    QUALIFIER NEW, NONNEGATABLE
    QUALIFIER MARK
    QUALIFIER GROUP, NONNEGATABLE, VALUE (REQUIRED, LIST)
    QUALIFIER IGNORE

DEFINE TYPE EXTRACT_KWDS
    KEYWORD FULL, NONNEGATABLE

DEFINE VERB CANCEL
    ROUTINE CMD_CANCEL
    PARAMETER P1, LABEL=ARTNUM, VALUE (TYPE=$NUMBER)

DEFINE VERB DEFINE
    QUALIFIER KEY, SYNTAX=DEFKEY

DEFINE SYNTAX DEFKEY
    ROUTINE CMD_DEFKEY
    PARAMETER P1, LABEL=DKCMD, VALUE (TYPE=$REST_OF_LINE)

DEFINE VERB PRINT
    ROUTINE CMD_PRINT
    QUALIFIER CANCEL, SYNTAX=PRINT_CANCEL
    QUALIFIER PRINT, SYNTAX=PRINT_NOW
    QUALIFIER NOW, SYNTAX=PRINT_NOW
    PARAMETER P1, LABEL=ARTRNG, VALUE (LIST)
    QUALIFIER HEADERS, NEGATABLE
    QUALIFIER ROTATE
    QUALIFIER AFTER, NONNEGATABLE, VALUE (TYPE=$DATETIME)
    QUALIFIER BURST, VALUE (TYPE=ALLONE)
    QUALIFIER COPIES, NONNEGATABLE, VALUE (TYPE=$NUMBER)
    QUALIFIER FEED
    QUALIFIER FLAG, VALUE (TYPE=ALLONE)
    QUALIFIER FORM, NONNEGATABLE, VALUE (REQUIRED)
    QUALIFIER HOLD
    QUALIFIER NAME, NONNEGATABLE, VALUE (REQUIRED)
    QUALIFIER NOTIFY
    QUALIFIER PARAMETERS, NONNEGATABLE, VALUE (REQUIRED, LIST)
    QUALIFIER QUEUE, NONNEGATABLE, VALUE (REQUIRED)
    QUALIFIER SPACE
    QUALIFIER TRAILER, VALUE (TYPE=ALLONE)

DEFINE TYPE ALLONE
    KEYWORD ALL
    KEYWORD ONE

DEFINE SYNTAX PRINT_CANCEL
    ROUTINE CMD_PRINT_CANCEL
    NOPARAMETERS
    NOQUALIFIERS

DEFINE SYNTAX PRINT_NOW
    ROUTINE CMD_PRINT_NOW
    NOPARAMETERS
    QUALIFIER NOTIFY